kb?: func [d] [round/to (length? d) / 1024 .1]
to-kb: func [d] [round/to (d) / 1024 .1]

free-mem: func ['word] [set :word make none! recycle]

kb?: func [d] [
  t: type? d
  either any [t == file! t == url!] [
    i: info? d
    round/to i/size / 1024 .1
  ][
    round/to (length? d) / 1024 .1
  ]  
]

REBOL [
	Title:   "BUILD Duplex"
	Date:	 12-Jan-2010
	Author:  "Marco"
	Version: 1.0.0
	Email:   mvri@bluewin.ch
	File:	 %build-package.r
]

build-package: func [
    "Build, compress and saves a package to a file or url."
    where [file! url! binary!] "Where to save it."
    list [file! url! block!] "List of script to include into the package."
    header [block! object!] "Header block or object"
][
	list: load list
	block: copy []

	foreach [flag item] list [
		print ["Loading" item]
		script: load/header item
		append block compose/deep [
			if (flag) [
				if not system/options/quiet [print rejoin [{Script: "} (script/1/title) {" (} (script/1/date) {)"}]]
				do decompress as-binary (
					as-string compress mold/only next script
				)
			]
		]
	]
	save/header where block header
]


print "Building the REBOL Duplex"

build-package %rebol.r [
	yes http://www.rebol.org/download-a-script.r?script-name=run.r
	yes http://www.rebol.org/download-a-script.r?script-name=sql-protocol.r
 	yes http://www.rebol.org/download-a-script.r?script-name=easy-soccer.r
 	yes http://www.rebol.org/download-a-script.r?script-name=prolog.r
 	view? http://www.rebol.org/download-a-script.r?script-name=rebzip.r
] compose [
	Title:   "REBOL duplex"
	Date:	 (now/date)
	Author:  "Marco"
	Version: 1.0.0
	Email:   mvri@bluewin.ch
	File:	 %rebol.r
	Comment: {Please copy the new rebol.r file into the same directory as your rebol.exe}
]

print ""
print ""
print "REBOL Duplex is build"
print ""
print "Please copy the new rebol.r file into the same directory as your rebol.exe"
print ""
ask "Thanks for using REBOL Duplex"

REBOL [
	Title:   "BUILD Duplex"
	Date:	 12-Jan-2010
	Author:  "Marco"
	Version: 1.0.1
	Email:   mvri@bluewin.ch
	File:	 %build-package.r
]

build-package: func [
    "Build, compress and saves a package to a file or url."
    where [file! url! binary!] "Where to save it."
    list [file! url! block!] "List of script to include into the package."
    header [block! object!] "Header block or object"
    /local result scripts
][
	append-script: func [
    	list [file! url! block!]
	    /local item product need condition file
	][
		list: to-block list
		parse list [any [
			opt [#product set product [word! | block!]]
			opt [#need set need [file! | url! | block!]]
			opt [#all set condition [word! | block!]]
			set item [file! | url!] (
				unless find scripts item [
					append scripts item
					print ["Loading" item]
					item: load/header item
					if need [append-script need]
					append result compose/deep [
						if all [
							(either condition [condition][])
							(either product	[compose/deep [find [(product)] system/product]][])
						][
							unless system/options/quiet [print rejoin [{Script: "} (item/1/title) {" (} (item/1/date) {)"}]]
							do decompress as-binary (
								as-string compress mold/only next item
							)
						]
					]
					product: condition: need: none
				]
			)
		]]
	]

	result: copy []
	scripts: copy []
	append-script load list
	save/header where result header
]



print "Building the REBOL Duplex"
print ""

build-package %rebol.r [

; Core extension
	http://www.rebol.org/download-a-script.r?script-name=run.r
	#product [core] http://www.rebol.org/download-a-script.r?script-name=sql-protocol.r
 	#need http://www.rebol.org/download-a-script.r?script-name=easy-soccer.r 
 		http://www.rebol.org/download-a-script.r?script-name=prolog.r
	#need http://www.rebol.org/download-a-script.r?script-name=easy-soccer.r
		http://www.rebol.org/download-a-script.r?script-name=age.r

; View extension
 	#all view? http://www.rebol.org/download-a-script.r?script-name=rebzip.r
 	#product [view] http://97.107.135.89/www.hmkdesign.dk/data/projects/vid-ext-kit/downloads/vid-ext-kit.r
 	
] compose [
	Title:   "REBOL duplex"
	Date:	 (now/date)
	Author:  "Marco"
	Version: 1.0.0
	Email:   mvri@bluewin.ch
	File:	 %rebol.r
	Comment: {Please copy the new rebol.r file into the same directory as your rebol.exe}
]

print ""
print ""
print "REBOL Duplex is build"
print ""
print "Please copy the new rebol.r file into the same directory as your rebol.exe"
print ""
ask "Thanks for using REBOL Duplex"

;***** Conversion function from/to CSV format
csv-to-block: func [
	"Convert a string of CSV formated data to a Rebol block. First line is header."
	csv-data [string!] "CSV data."
	/separator separ [char!] "Separator to use if different of comma (,)."
	/without-header "Do not include header in the result."
	/local out line start end this-string header record value data chars spaces chars-but-space
	; CSV format information http://www.creativyst.com/Doc/Articles/CSV/CSV01.htm
] [
	out: copy []
	separ: any [separ #","]
	
	; This function handle replacement of dual double-quote by quote while copying substring
	this-string: func [s e] [replace/all copy/part s e {""} {"}]
	; CSV parsing rules
	header: [(line: copy []) value any [separ value] (if not without-header [append/only out line])]
	record: [(line: copy []) value any [separ value] (append/only out line)]
	value: [any spaces data any spaces (append line this-string start end)]
	data: [start: some chars-but-space end: | #"^"" start: any [some chars | {""} | #"," | newline] end: #"^""]
	chars: complement charset rejoin [ {"} separ newline]
	spaces: charset exclude { ^-} form separ
	chars-but-space: exclude chars spaces
	
	parse/all csv-data [header any [newline record] any newline end]
	out
]

block-to-csv: func [
	"Convert a block of blocks to a CSV formated string." 
	blk-data [block!] "block of data to convert"
	/separator separ "Separator to use if different of comma (,)."
	/local out csv-string record value v
] [
	out: copy ""
	separ: any [separ #","]
	; This function convert a string to a CSV formated one
	csv-string: func [val] [head insert next copy {""} replace/all copy val {"} {""} ]
	record: [into [some [value (append out #",")]]]
	value: [set v string! (append out csv-string v) | set v any-type! (append out form v)]
	
	parse/all blk-data [any [record (remove back tail out append out newline)]]
	out
]

;***** Conversion function from/to CSV format
csv-to-block: func [
	"Convert a string of CSV formated data to a Rebol block. First line is header."
	csv-data [string!] "CSV data."
	/separator separ [char!] "Separator to use if different of comma (,)."
	/without-header "Do not include header in the result."
	/local out line start end this-string header record value data chars spaces chars-but-space
	; CSV format information http://www.creativyst.com/Doc/Articles/CSV/CSV01.htm
] [
	out: copy []
	separ: any [separ #","]
	
	; This function handle replacement of dual double-quote by quote while copying substring
	this-string: func [s e] [replace/all copy/part s e {""} {"}]
	; CSV parsing rules
	header: [(line: copy []) value any [separ value | separ (append line none)] (if not without-header [append/only out line])]
	record: [(line: copy []) value any [separ value | separ (append line none)] (append/only out line)]
	value: [any spaces data any spaces (append line this-string start end)]
	data: [start: some chars-but-space any [some spaces some chars-but-space] end: | #"^"" start: any [some chars | {""} | separ | newline] end: #"^""]
	chars: complement charset rejoin [ {"} separ newline]
	spaces: charset exclude { ^-} form separ
	chars-but-space: exclude chars spaces
	
	parse/all csv-data [header any [newline record] any newline end]
	out
]