REBOL [
version: 0.1.0
]
ctx: context [
version: does [
print system/script/header/version
]
]

>> do %ctx.r
Script: "Untitled" (none)
>> ctx/version
** Script Error: Cannot use path on none! value
** Where: version
** Near: print system/script/header/version
>>

REBOL []
my-ctx: context [

]

>> do %my-ctx.r
>> my-ctx
my-ctx>>

REBOL [
  Title:   "tests-externe "
  Date:    7-Jul-2011
]

h: load/header %lib-interne.r  ; tu recuperes directement le header de la lib
do %lib-interne.r
print h/1/version
print ctx/version      ; idem au-dessus mais via le ctx
print ctx/version-ctx   ; le versionning interne du ctx 
halt

REBOL [
  Title:   "lib interne"
  Date:    7-Jul-2011
  version: 0.0.1
]

ctx: context [
version: system/script/header/version
version-ctx: 0.0.2
]

>> do %rem.r
>> rem
Welcome to REBOL External Modules
version 0.1.0
rem>>

REBOL [
  Title:   "tests-externe "
  Date:    8-Jul-2011
]
do %lib-interne.r
halt  

REBOL [
  Title:   "REBOL External Modules"
  Date:    8-Jul-2011
  version: 0.0.1
]


ctx: context [
print join {rem
Welcome to REBOL External Modules
version } system/script/header/version
system/console/prompt: "rem>>"
{.. puis le contexte ..}
]

REBOL [
	title: "REM"
	version: 0.1.0
]

rem-ctx: context [
	; on sauve le prompt système et la version du script pendant qu'elle est accessible
	sys-prompt: system/console/prompt
	version: system/script/header/version

	; on sauve les fonctions redefinis
	sys-exit: :exit
	sys-add: :add
	sys-help: :help
	

	; Init du module
	init: does [
		print join "Welcome in REM v" version
		system/console/prompt: "rem>>"

		; On créé les fonctions de REM
		set 'add func [ a b] [print [a "+" b "=" a + b]]
	
		set 'help does [
			print "Commandes disponibles : Add, Help ou Exit"
		]
		
		set 'exit does [
			; restauration de l'environnement système
			system/console/prompt: sys-prompt
			exit: :sys-exit
			add: :sys-add
			help: :sys-help
		]
	]
]

; la fonction de lancement
set 'rem does [
	rem-ctx/init
]

>> do %rem.r
>> add 5 4
== 9
>> rem
Welcome in REM v0.1.0
rem>>help
Commandes disponibles : Add, Help ou Exit
rem>>add 5 4
5 + 4 = 9
rem>>exit
>> add 5 4
== 9
>>

REBOL [
	title: "REM"
	version: 0.1.0
]

rem-ctx: context [
	; on sauve le prompt système et la version du script pendant qu'elle est accessible
	sys-prompt: system/console/prompt
	version: system/script/header/version

	; on y sauve les fonctions redéfinies par le module
	sys-funcs: []
	

	; Init du module : défini les fonctions de REM et sauve les fonctions existantes du sytème
	init: has [funcs] [
		print join "Welcome in REM v" version
		system/console/prompt: "rem>>"

		; On va créé les fonctions de REM
		; pour ça on récupère la listes des "membres" du contexte définis à partir de 'exit = fonctions du module
		funcs: find first self 'exit
		
		clear sys-funcs
		
		; pour chaque word! du contexte
		foreach f funcs [
			; Si c'est pas un mot du contexte global
			either unset? get/any in system/words :f [
				; on ajoute le code pour l'en enlever en sortie
				append sys-funcs reduce ['unset to-lit-word :f]
			] [
				; on ajoute le code pour remettre l'original en sortie (attention, on ne peut pas mettre la fonction directement, des fois que ce serait une native! action!)
				append sys-funcs reduce ['set to-lit-word :f 'pick reduce [get bind :f system/words] 1]
			]
			
			; maintenant on met notre fonction en place
			set to-lit-word :f get in self :f
		]
	]

	; fonction qui permet de quitter REM en restaurant les fonctions originales
	exit: does [	; existe dans Rebol
		; restauration de l'environnement système
		system/console/prompt: sys-prompt
		do sys-funcs
	]
	
	; fonctions du module
	rem: does [	; n'existe pas dans Rebol
		; Evite de relancer REM ce qui re-sauvegarderait les fonctions et donc celles de REM et non plus celles du système
		print "REM already running !"
	]
	
	add: func [ a b] [print [a "+" b "=" a + b]]	; existe dans Rebol
	
	sub: func [ a b] [print [a "-" b "=" a - b]]	; n'existe pas dans Rebol

	help: does [	; existe dans Rebol
		print "Commandes disponibles : Add, Help ou Exit"
	]
	
]

; la fonction de lancement
set 'rem does [
	rem-ctx/init
]