REBOL []

song: load decompress #{
...
reprendre les données du script ttp://www.rebol.org/cgi-bin/cgiwrap/rebol/download-a-script.r?script-name=demo-ay.r
...
}

; This is the mixer that mix 3 channel and noise.
current-a: 0 ; Current channel A position
current-b: 0 ; Current channel B position
current-c: 0 ; Current channel C position
current-n: 0 ; Current noise position

append-mix: func [
    "Mix channel a, b, c and noise, and append it to data"
    data [binary! string!] "Sound data"
    length [number!] "Sound length"
    channel-a [block!] "Channel A [Periode Amplitude]"
    channel-b [block!] "Channel B [Periode Amplitude]"
    channel-c [block!] "Channel C [Periode Amplitude]"
    noise [number!] "Noise periode (Amplitude is generated randomly)"
    /square "Produce a square wave"
][
    loop length [
        insert tail data to char! 128 + (
            channel-a/2 * either zero? channel-a/1 [0][
                current-a: current-a + (360 / channel-a/1)
                either square [sign? sine current-a][sine current-a]
            ]
        ) + (
            channel-b/2 * either zero? channel-b/1 [0][
                current-b: current-b + (360 / channel-b/1)
                either square [sign? sine current-b][sine current-b]
            ]
        ) + (
            channel-c/2 * either zero? channel-c/1 [0][
                current-c: current-c + (360 / channel-c/1)
                either square [sign? sine current-c][sine current-c]
            ]
        ) + (
            (-1 + random 32) * either zero? noise [0][
                current-n: current-n + (360 / noise)
                either square [sign? sine current-n][sine current-n]
            ]
        )
    ]
]

print "running"

; Set up the sound sample parameters:
sample: make sound [
    rate: 44200 
    channels: 1
    bits: 8
    volume: 1
    data: #{}
]

; Ratio and length
ratio: sample/rate / (3579545 / 16 / 2)
length: sample/rate / 100
max-length: sample/rate * 4

; open sound port
wait 0
sound-port: open/no-wait sound://

foreach [nb A0 A1 B0 B1 C0 C1 noise mixer volA volB volC Ev0 Ev1 Shape JoyA JoyB] song [
    loop nb [
        append-mix/square sample/data length
            reduce [ratio * (A1 and 15 * 256 + A0) 2 * (volA and 15)]
            reduce [ratio * (B1 and 15 * 256 + B0) 2 * (volB and 15)]
            reduce [ratio * (C1 and 15 * 256 + C0) 2 * (volC and 15)]
            ratio * (noise and 31)
    ]
    if max-length < length? sample/data [
        wait sound-port
        insert sound-port sample
        clear sample/data recycle
    ]
]
unless zero? length? sample/data [
    wait sound-port
    insert sound-port sample
    clear sample/data recycle
]

ask "Done"

REBOL []

song: load decompress #{
...
reprendre les données du script ttp://www.rebol.org/cgi-bin/cgiwrap/rebol/download-a-script.r?script-name=demo-ay.r
...
}

; This is the mixer that mix 3 channel and noise.
current-a: 0 ; Current A position
current-b: 0 ; Current B position
current-c: 0 ; Current C position
current-n: 0 ; Current noise position

append-mix: rebcode [
    {Mix channel A, B, C and noise, and append it to data
        - Amplitude must be between 0 and 31
        - Square flag produce square wave}
    data [binary!] "Sound data"
    length [integer!] "Sound length"
    channel-a [block!] "Channel A [periode amplitude square-flag]"
    channel-b [block!] "Channel B [periode amplitude square-flag]"
    channel-c [block!] "Channel C [periode amplitude square-flag]"
    noise [block!] "Noise [periode max-amplitude square-flag] (Amplitude is generated randomly)"
    /local result value 
        step-a ampl-a sqre-a
        step-b ampl-b sqre-b
        step-c ampl-c sqre-c
        step-n maxi-n sqre-n ampl-n
][
; Initialize channel A value
; --------------------------
    pick step-a channel-a 1
    to-int step-a
    sett step-a ift [
        set value 72000
        div.i value step-a
        set.i step-a value
    ]
    pick ampl-a channel-a 2
    to-dec ampl-a
    pick sqre-a channel-a 3
    to-int sqre-a

; Initialize channel B value
; --------------------------
    pick step-b channel-b 1
    to-int step-b
    sett step-b ift [
        set value 72000
        div.i value step-b
        set.i step-b value
    ]
    pick ampl-b channel-b 2
    to-dec ampl-b
    pick sqre-b channel-b 3
    to-int sqre-b

; Initialize channel C value
; --------------------------
    pick step-c channel-c 1
    to-int step-c
    sett step-c ift [
        set value 72000
        div.i value step-c
        set.i step-c value
    ]
    pick ampl-c channel-c 2
    to-dec ampl-c
    pick sqre-c channel-c 3
    to-int sqre-c

; Initialize noise value
; ----------------------
    pick step-n noise 1
    to-int step-n
    sett step-n ift [
        set value 72000
        div.i value step-n
        set.i step-n value
    ]
    pick maxi-n noise 2
    to-int maxi-n
    pick sqre-n channel-n 3
    to-int sqre-n

; Generate the wave points for the given length
; ---------------------------------------------
    loop length [
        set result 128.0
; Channel A wave point      
        sett step-a ift [
            add.i current-a step-a
            rem.i current-a 72000
            set value current-a
            to-dec value
            div.d value 200.0
;           sin value ; !!! ne marche pas -> remplacé par la ligne suivante (apply)
            apply value sine [value]
            sett sqre-a ift [sign value to-dec value]
            mul.d value ampl-a
            add.d result value
        ]
; Channel B wave point      
        sett step-b ift [
            add.i current-b step-b
            rem.i current-b 72000
            set value current-b
            to-dec value
            div.d value 200.0
;           sin value ; !!! ne marche pas -> remplacé par la ligne suivante (apply)
            apply value sine [value]
            sett sqre-b ift [sign value to-dec value]
            mul.d value ampl-b
            add.d result value
        ]
; Channel C wave point      
        sett step-c ift [
            add.i current-c step-c
            rem.i current-c 72000
            set value current-c
            to-dec value
            div.d value 200.0
;           sin value ; !!! ne marche pas -> remplacé par la ligne suivante (apply)
            apply value sine [value]
            sett sqre-c ift [sign value to-dec value]
            mul.d value ampl-c
            add.d result value
        ]
; Noise wave point      
        sett step-n ift [
            add.i current-n step-n
            rem.i current-n 72000
            set value current-n
            to-dec value
            div.d value 200.0
;           sin value ; !!! ne marche pas -> remplacé par la ligne suivante (apply)
            apply value sine [value]
            sett sqre-n ift [sign value to-dec value]
            set.i ampl-n maxi-n
            add.i ampl-n 1
            randz ampl-n
            to-dec ampl-n
            mul.d value ampl-n
            add.d result value
        ]
; Append result to data
        to-int result
        tail data
        insert data result 1
    ]
]

print "running"

; Set up the sound sample parameters:
sample: make sound [
    rate: 44200 
    channels: 1
    bits: 8
    volume: 1
    data: #{}
]

; Ratio and length
ratio: sample/rate / (3579545 / 16 / 2)
length: to-integer sample/rate / 100
max-length: sample/rate * 4

; open sound port
wait 0
sound-port: open/no-wait sound://

s: now/time/precise
foreach [nb A0 A1 B0 B1 C0 C1 noise mixer volA volB volC Ev0 Ev1 Shape JoyA JoyB] song [
    loop nb [
        append-mix sample/data length
            reduce [ratio * (A1 and 15 * 256 + A0) 2 * (volA and 15) true]
            reduce [ratio * (B1 and 15 * 256 + B0) 2 * (volB and 15) true]
            reduce [ratio * (C1 and 15 * 256 + C0) 2 * (volC and 15) true]
            reduce [ratio * (noise and 31) 31 true]
    ]
    if max-length < length? sample/data [
        print "Wait"
        wait sound-port
        insert sound-port sample
        clear sample/data recycle
        print "Compose"
    ]
]

unless zero? length? sample/data [
    wait sound-port
    insert sound-port sample
    clear sample/data recycle
]
wait sound-port

ask "Done"

append-mix: func [
	{Mix channel a, b, c and noise, and append it to data
		- Amplitude must be between 0 and 31
		- Square flag produce square wave}
    data [binary!] "Sound data"
    length [integer!] "Sound length"
    channel-a [block!] "Channel A [Periode Amplitude Square]"
    channel-b [block!] "Channel B [Periode Amplitude Square]"
    channel-c [block!] "Channel C [Periode Amplitude Square]"
    noise [block!] "Noise [Periode Amplitude Square] (Amplitude is generated randomly)"
    /local step-a step-b step-c step-n
][
	step-a: either zero? channel-a/1 [0][360 / channel-a/1]
	step-b: either zero? channel-b/1 [0][360 / channel-b/1]
	step-c: either zero? channel-c/1 [0][360 / channel-c/1]
	step-n: either zero? noise/1 [0][360 / noise/1]
    loop length [
        insert tail data to char! 128 + (either zero? step-a [0][
            current-a: remainder current-a + step-a 360
            channel-a/2 * either channel-a/3 [sign? sine current-a][sine current-a]
        ]) + (either zero? step-b [0][
            current-b: remainder current-b + step-b 360
            channel-b/2 * either channel-b/3 [sign? sine current-b][sine current-b]
        ]) + (either zero? step-c [0][
            current-c: remainder current-c + step-c 360
            channel-c/2 * either channel-c/3 [sign? sine current-c][sine current-c]
        ]) + (either zero? step-n [0][
            current-n: remainder current-n + step-n 360
            (random noise/2) * either noise/3 [sign? sine current-n][sine current-n]
        ])
    ]
]

    ; Init de la table des sinus si pas déjà fait
    if empty? sin-table: [] [
        repeat sin 361 [insert tail sin-table sine sin - 1]
        ; Cette fonction va être utiliser à la place de la fonction 'sine de Rebol
        sin: func [v][pick sin-table v + 1]
    ]

; Channel A wave point      
        sett step-a ift [
            add.i current-a step-a
            rem.i current-a 72000
            set.i value current-a
            div.i value 200
            pickz value sine-table value
            sett sqre-a ift [sign value to-dec value]
            mul.d value ampl-a
            add.d result value
        ]

some example code (in C, but easy to rewrite):

float a = 2.f*(float)sin(Pi*frequency/samplerate);

float s[2];

s[0] = 0.5f;
s[1] = 0.f;

loop:
s[0] = s[0] - a*s[1];
s[1] = s[1] + a*s[0];
output_sine = s[0];
output_cosine = s[1]

>> bench 1000000 [sine 90]
== 0:00:00.381
>> x: [1 2 3]
== [1 2 3]
>> bench 1000000 [x/2]
== 0:00:00.42
>> bench 1000000 [pick x 2]
== 0:00:00.311
>> bench 1000000 [sine 26]
== 0:00:00.391
>>