view
neoreb3-Feb-2007/20:07:21+1:00
rebol []

alphabet: [A B C D E F G H I J K L M N O P Q R S T U V W X Y Z]


le code ci-dessous ne marche pas...

view layout [

   across
   repeat count 26 [button form alphabet/:count]
   
]


vous voyez ce que je veux faire. Je sais, c'est une question de noob mais comment faire (de manière compliquée...) ce qui aurait pu être simple (snif) ?
neoreb3-Feb-2007/23:03:59+1:00
bon je me reponds. j'ai trouve ça. Ca marche mais je trouve ca moins lisible.

rebol []

alphabet: [A B C D E F G H I J K L M N O P Q R S T U V W X Y Z]

tableau: [view layout [across]]

repeat count 26 [append tableau/3 compose [toggle (mold alphabet/:count) blue green 30x30]]

do tableau
Goldevil4-Feb-2007/11:12:12+1:00
Je te propose ceci :

rebol []

alphabet: [A B C D E F G H I J K L M N O P Q R S T U V W X Y Z]

layout_block: [ across ]

repeat count 26 [ append layout_block reduce ['button 30x30 form alphabet/:count] ]

view layout layout_block


Un bloc de type layout est un dialecte différent de Rebol. Donc je compose le script VID en rebol et je l'envoie à l'instruction 'layout une fois réalisé.

Dans ton deuxième script, tu as utilisé le concept mais de manière originale. Tu as construit un script rebol en rebol. Ce script étant composé entre autre d'un block layout.

L'équivalent de ton second script.
rebol []

alphabet: [A B C D E F G H I J K L M N O P Q R S T U V W X Y Z]

layout_block: [ across ]

repeat count 26 [ 
	append layout_block reduce ['toggle 30x30 blue green form alphabet/:count] 
]

view layout layout_block
neoreb4-Feb-2007/17:59:08+1:00
merci Goldevil
ton script est plus propre que le mien.
j'ai bien compris pourquoi le premier ne marchait pas.
C'est dommage qu'on ne puisse pas melanger du rebol avec du dialect vid
Didec5-Feb-2007/12:16+1:00
On peut, mais de manière limité.

Par exemple, on peut faire des calculs d'entier ou de pair! (pour une position ou une taille) quelques opérations sur des chaines (join, reduce, compose...) MAIS PAS d'instructions "complexes" type boucles !
On peut cependant utiliser les parenthèses pour effectuer un traitement complexe, dont le résultat final sera un élement du block VID.

Exemple :
rebol []

pos: 20x20
mul: 3
ch1: "Le début du titre, "
ch2: "sa suite "
ch3: 'et-sa-fin

view layout [
	at mul * pos
	vh1 join join ch1 ch2 compose [(replace/all form ch3 "-" " ")]
	text (loop 5 [append "" ".-"])
]

; equivalent a :
view layout [
	at 60x60
	vh1 "Le début du titre, sa suite et sa fin"
	text ".-.-.-.-.-"
]

Ou comment faire compliqué quand on peut faire simple
neoreb5-Feb-2007/19:14:42+1:00

ok merci pour les infos

Login required to Post.


Powered by RebelBB and REBOL 2.7.8.4.2